Каталог статей

Главная » Статьи » Материалы по 1С » Объекты конфигурации и типы данных

План счетов

Объект конфигурации План счетов предназначен для описания структуры хранения информации о совокупности синтетических счетов предприятия, которые созданы для группировки данных о его хозяйственной деятельности.

На основе объекта конфигурации План счетов платформа создает в базе данных таблицы, в которых будет храниться информация о том, какие счета и каким образом будет использовать предприятие.

План счетов в системе «1С:Предприятие» поддерживает иерархию субсчетов: к каждому счету первого уровня может быть открыто несколько субсчетов, которые, в свою очередь, могут иметь свои субсчета, и так далее.

По любому счету или субсчету может вестись аналитический учет в разрезе субконто, описанных в плане видов характеристик. Связь между планом счетов и планом видов характеристик задается разработчиком на этапе конфигурирования.

Для описания используемых субконто система создает в плане счетов специальную табличную часть ВидыСубконто, которая не видна в конфигураторе (но доступна средствами встроенного языка).

Для каждого счета есть возможность задать несколько видов учета (например, количественный и валютный). Виды учета задаются при помощи подчиненных объектов конфигурации признак учета.

Также существует возможность определить несколько видов учета субконто (например, суммовой, валютный или количественный). Виды учета субконто задаются при помощи подчиненных объектов конфигурации признак учета субконто.

При добавлении счетов, в том числе предопределенных, задаются признаки учета и субконто, в разрезе которых будет вестись учет.

Свойство Только обороты схоже по своему назначению с признаками учета субконто. Оно ограничивает хранение итогов по субконто счета только хранением оборотов, исключая из таблиц итогов остатки. Это может быть необходимо в случае, когда остатки по субконто просто не имеют смысла.

По умолчанию счета создаются с контролем баланса (при проводке значение измерения по дебету и кредиту должны быть одинаковые), но существует возможность этот контроль отключить. Делается это с помощью свойства счета «Забалансовый»

Маска определяет формат номеров счета (формат маски)

У каждого счета есть свойство "Порядок". Оно обязательно вводится для предопределенных счетов, но не формируется автоматически при создании счета в клиенте.

Свойство "Порядок" отвечает за сортировку счетов. Чтобы оно было заполнено для счетов вводимых в режиме клиента, м модуле формы или объекта счета надо добавить код:

Порядок = ПолучитьПорядокКода();

При выполнении метода ПолучитьПорядокКода() происходит преобразование номера счета с учетом маски. Если используется символ @, то порядок будет дополнен при необходимости пробелами.

Длина порядка содержит количество символов в поле "порядок", включая разделители.

Свойство «Автопорядок по коду» позволяет автоматически формировать порядок для счета и использовать его в сортировках в формах списков и запросах. При указании сортировки по коду, система автоматически подменить сортировку по коду на сортировку по порядку.

Например, есть счета 10.11 (10.11) и 10.2 (10. 2). При отключенном "Автопорядок по коду" сортировка по коду даст результат:
10.11
10.2

(сортировка по строке).

Если свойство "Автопорядок по коду" установлено, то та же сортировка даст результат, который соответствует сортировке по порядку:

10.2
10.11

Виды субконто - ссылка на план видов характеристик, в котором задается разрез аналитического учета.

Для каждого счета можно настроить учет аналитики по видам субконто. Таким образом мы расширяем детализацию ведения учета по счету, т.е. можно не просто получить обороты и остатки по счету 51 (РасчетныеСчета), а в разрезе, например, Банковских счетов. По сути Субконто - это необязательные измерения, которые пользователь может настроить, в в том числе, в режиме клиента.

Не рекомендуется включать в тип значения характеристик какие-либо типы, кроме ссылочных, так как это повышает нагрузку на систему.

Максимальное количество субконто - количество субконто, которое можно настроить на счете.

Проверка на превышение максимального количества видов субконто для плана счетов будет выполняться только при записи счета. Эту особенность надо учитывать при программном добавлении субконто на счет.

Способ программно определить, установлено ли субконто для счета.

В данном примере определяем установлено ли субконто Сотрудники для счета Касса.

Счет = ПланыСчетов.ОсновнойПланСчетов.Касса;
ВидСубконто = ПланыВидовХарактеристик.ВидыСубконто.Сотрудники;
Если Счет.ВидыСубконто.Найти(ВидСубконто,"ВидСубконто") = Неопределено Тогда
...
КонецЕсли;

Настройка выбора субконто и значений субконто в диалогах

Для того, чтобы в форме выбора отображались характеристики конкретного субконто, необходимо настроить связи:
1) Связь по типу - позволяет ограничить вывод в диалоге выбора типы значений, оставляя только те, которые соответсвуют нужному субконто
2) Связи параметров выбора - позволяет ограничить выбор значений, оставляя только те, которые относятся только к нужному субконто

Если счет имеет нескольку субконто, то часто надо ограничить выбор типа данных, который соответсвтует определенному субконто счета.
Например у счета 2 субконто и надо настроить таким образом, что для поля Субконто1 были доступны для выбора только типы данных, определенных для 1-го субконто счета
Настройка связей будет выглядеть следующим образом:

Особенностью здесь является то, что в связи по типу задается номер элемента связи, который соответствует порядковому номеру вида субконто: для 1-го субконто надо задать 1, а для 2-го субконто надо задать 2.

Часто у разных счетов задано разное количество субконто или вообще не задано. В этом случае на форме надо позаботиться о том, чтобы не выводились элементы для несуществующих субконто счета и привести значения субконто к нужному типу. Для этого для события "ПриИзменении" счета напишем обработчик:

&НаКлиенте
Процедура СчетПриИзменении(Элемент)

   ВыбиратьТипСубконто();

   УстановитьВидимостьСубконто();

КонецПроцедуры

&НаСервере
Процедура ВыбиратьТипСубконто()

   ЧислоСубконто = Объект.Счет.ВидыСубконто.Количество();

   Для Сч = 1 По ЧислоСубконто Цикл
       ТипСубконто = Объект.Счет.ВидыСубконто[Сч - 1].ВидСубконто.ТипЗначения;
       Элементы["Субконто" + Сч].ВыбиратьТип = (ТипСубконто.Типы().Количество() > 1); // если тип субконто составной, то делаем видимой кнопку выбора типа

// если тип значения не соответствует типу субконто, то приводим его значение к нужному типу.
       Если ТипСубконто.ПривестиЗначение(Объект["Субконто" + Сч]) <> Объект["Субконто" + Сч] Тогда
           Объект["Субконто" + Сч] = ТипСубконто.ПривестиЗначение(Объект["Субконто" + Сч]);
       КонецЕсли;
   КонецЦикла;

КонецПроцедуры

&НаСервере
Процедура УстановитьВидимостьСубконто()

Для НомерСубконто = 1 по 2 Цикл

       Если (НомерСубконто <= Объект.Счет.ВидыСубконто.Количество()) и (НЕ Объект.Счет.Пустая()) Тогда
           Элементы["Субконто"+НомерСубконто].Заголовок = Строка(Объект.Счет.ВидыСубконто[НомерСубконто-1].ВидСубконто);
           Элементы["Субконто"+НомерСубконто].Видимость = Истина;
       Иначе
           Элементы["Субконто"+НомерСубконто].Видимость = Ложь;
       КонецЕсли;

КонецЦикла;

КонецПроцедуры

Иерархия

Любой счет может иметь субсчета. Субсчета могут появляться в процессе работы. Наличие субсчетов не означает, что по основному счету нельзя делать проводку. Если есть проводки по счету и его субсчетам, то при формировании отчетов система создаст служебный субсчет с названием счета, рядом с которым будут отображаться движения, произведенные по счету владельцу.